@echo off
setlocal EnableExtensions EnableDelayedExpansion

if "%SERVER_ROOT%"=="" set "SERVER_ROOT=C:\scumserver"
set "SERVER_ROOT_WINDOWS=%SERVER_ROOT:/=\%"
if "%SERVER_STEAM_APP_ID%"=="" set "SERVER_STEAM_APP_ID=3792580"
if "%SERVER_STEAMCMD_INSTALL_DIR_ARG%"=="" set "SERVER_STEAMCMD_INSTALL_DIR_ARG=+force_install_dir"
if "%SERVER_STEAMCMD_UPDATE_ARGS%"=="" set "SERVER_STEAMCMD_UPDATE_ARGS=+login anonymous +app_update 3792580 +quit"
if "%SERVER_EXECUTABLE_REF%"=="" set "SERVER_EXECUTABLE_REF=SCUM\Binaries\Win64\SCUMServer.exe"
if "%SERVER_INSTALL_DIR%"=="" set "SERVER_INSTALL_DIR=%SERVER_ROOT_WINDOWS%"
set "SERVER_INSTALL_DIR_WINDOWS=%SERVER_INSTALL_DIR:/=\%"
set "SERVER_INSTALL_DIR_STEAM=%SERVER_INSTALL_DIR_WINDOWS:\=/%"
if "%SERVER_STEAMCMD_DIR%"=="" call :default_steamcmd_dir
set "SERVER_STEAMCMD_DIR_WINDOWS=%SERVER_STEAMCMD_DIR:/=\%"
if "%SERVER_STEAMCMD_MAX_ATTEMPTS%"=="" set "SERVER_STEAMCMD_MAX_ATTEMPTS=3"
if "%SERVER_STEAMCMD_RETRY_SECONDS%"=="" set "SERVER_STEAMCMD_RETRY_SECONDS=30"

set "STEAMCMD_DIR=%SERVER_STEAMCMD_DIR_WINDOWS%"
set "STEAMCMD_EXE=%STEAMCMD_DIR%\steamcmd.exe"
set "SCUM_EXE_MARKER=%SERVER_ROOT_WINDOWS%\.scum-exe-path"

if not exist "%SERVER_ROOT_WINDOWS%" mkdir "%SERVER_ROOT_WINDOWS%"
if not exist "%STEAMCMD_DIR%" mkdir "%STEAMCMD_DIR%"
if not exist "%SERVER_INSTALL_DIR_WINDOWS%" mkdir "%SERVER_INSTALL_DIR_WINDOWS%"
if /I "%STEAMCMD_DIR%"=="%SERVER_INSTALL_DIR_WINDOWS%" exit /b 3

if not exist "%STEAMCMD_EXE%" (
  powershell -NoProfile -ExecutionPolicy Bypass -Command "[Net.ServicePointManager]::SecurityProtocol=[Net.SecurityProtocolType]::Tls12; $zip=Join-Path $env:STEAMCMD_DIR 'steamcmd.zip'; Invoke-WebRequest -Uri 'https://steamcdn-a.akamaihd.net/client/installer/steamcmd.zip' -OutFile $zip; Expand-Archive -Path $zip -DestinationPath $env:STEAMCMD_DIR -Force; Remove-Item $zip -Force"
  if errorlevel 1 exit /b 1
)

call :resolve_scum_exe
if exist "%SCUM_EXE%" call :stop_matching_scum
if errorlevel 1 exit /b 1

pushd "%STEAMCMD_DIR%"
set "SCUM_STEAMCMD_RESULT=1"
for /L %%A in (1,1,%SERVER_STEAMCMD_MAX_ATTEMPTS%) do (
  "%STEAMCMD_EXE%" %SERVER_STEAMCMD_INSTALL_DIR_ARG% "%SERVER_INSTALL_DIR_STEAM%" %SERVER_STEAMCMD_UPDATE_ARGS%
  set "SCUM_STEAMCMD_RESULT=!ERRORLEVEL!"
  if "!SCUM_STEAMCMD_RESULT!"=="0" goto steamcmd_done
  if not "%%A"=="%SERVER_STEAMCMD_MAX_ATTEMPTS%" timeout /T %SERVER_STEAMCMD_RETRY_SECONDS% /NOBREAK >nul
)
:steamcmd_done
popd
if not "%SCUM_STEAMCMD_RESULT%"=="0" exit /b %SCUM_STEAMCMD_RESULT%

call :resolve_scum_exe
if not exist "%SCUM_EXE%" exit /b 2
>"%SCUM_EXE_MARKER%" echo(%SCUM_EXE%
exit /b 0

:resolve_scum_exe
set "SCUM_EXE=%SERVER_ROOT_WINDOWS%\%SERVER_EXECUTABLE_REF:/=\%"
if exist "%SCUM_EXE%" exit /b 0
set "SCUM_EXE=%SERVER_INSTALL_DIR_WINDOWS%\%SERVER_EXECUTABLE_REF:/=\%"
if exist "%SCUM_EXE%" exit /b 0
set "SCUM_EXE=%SERVER_ROOT_WINDOWS%\steamcmd\steamapps\common\SCUM Server\%SERVER_EXECUTABLE_REF:/=\%"
if exist "%SCUM_EXE%" exit /b 0
set "SCUM_EXE=%SERVER_ROOT_WINDOWS%\SCUM Server\%SERVER_EXECUTABLE_REF:/=\%"
exit /b 0

:stop_matching_scum
if "%SCUM_EXE%"=="" exit /b 0
powershell -NoProfile -ExecutionPolicy Bypass -Command "$target=[IO.Path]::GetFullPath($env:SCUM_EXE); Get-CimInstance Win32_Process -Filter \"name='SCUMServer.exe'\" | Where-Object { $_.ExecutablePath -and ([IO.Path]::GetFullPath($_.ExecutablePath) -ieq $target) } | ForEach-Object { Stop-Process -Id $_.ProcessId -Force }"
exit /b %ERRORLEVEL%

:default_steamcmd_dir
for %%I in ("%SERVER_ROOT_WINDOWS%") do set "SERVER_ROOT_DRIVE=%%~dI"
if "%SERVER_ROOT_DRIVE%"=="" (
  set "SERVER_STEAMCMD_DIR=%SERVER_ROOT_WINDOWS%-steamcmd"
) else (
  set "SERVER_STEAMCMD_DIR=%SERVER_ROOT_DRIVE%\steamcmd"
)
exit /b 0